users/Profpatsch/haskell-module-deps/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

{ depot, pkgs, lib, ... }:

let
  bins = depot.nix.getBins pkgs.zathura [ "zathura" ]
    // depot.nix.getBins pkgs.haskellPackages.graphmod [ "graphmod" ]
    // depot.nix.getBins pkgs.graphviz [ "dot" ]
  ;

  # Display a graph of all modules in a project and how they depend on each other.
  # Takes the project directory as argument.
  # Open in zathura.
  haskell-module-deps = depot.nix.writeExecline "haskell-module-deps" { } [
    "pipeline"
    [ haskell-module-deps-with-filetype "pdf" "$@" ]
    bins.zathura
    "-"
  ];

  # Display a graph of all modules in a project and how they depend on each other.
  # Takes the project directory as argument.
  # Print a png to stdout.
  haskell-module-deps-png = depot.nix.writeExecline "haskell-module-deps-png" { } [
    haskell-module-deps-with-filetype
    "png"
    "$@"
  ];

  # Display a graph of all modules in a project and how they depend on each other.
  # Takes the file type to generate as first argument
  # and the project directory as second argument.
  haskell-module-deps-with-filetype = pkgs.writers.writeBash "haskell-module-deps-with-filetype" ''
    set -euo pipefail
    shopt -s globstar
    filetype="$1"
    rootDir="$2"
    ${bins.graphmod} \
      ${/*silence warnings for missing external dependencies*/""} \
      --quiet \
      ${/*applies some kind of import simplification*/""} \
      --prune-edges \
      "$rootDir"/src/**/*.hs \
      | ${bins.dot} \
          ${/*otherwise it’s a bit cramped*/""} \
          -Gsize="20,20!" \
          -T"$filetype"
  '';

in
depot.nix.readTree.drvTargets {
  inherit
    haskell-module-deps
    haskell-module-deps-png
    haskell-module-deps-with-filetype
    ;
}