users/tazjin/presentations/tvix-eval-2023/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

{ depot, pkgs, ... }:

let
  inherit (pkgs) fontconfig texlive stdenv imagemagick;

  tex = texlive.combine {
    inherit (texlive)
      babel
      babel-russian
      beamer
      beamertheme-metropolis
      etoolbox
      euenc
      extsizes
      fontspec
      listings
      xetex
      minted
      ms
      pgfopts
      scheme-basic
      translator;
  };

in
stdenv.mkDerivation {
  name = "progmsk-tvix-eval";
  src = ./.;

  nativeBuildInputs = [ tex imagemagick fontconfig ];

  FONTCONFIG_FILE = pkgs.makeFontsConf {
    fontDirectories = with pkgs; [ jetbrains-mono fira fira-code fira-mono ];
  };

  buildPhase = ''
    # LaTeX needs a cache folder in /home/ ...
    mkdir home
    export HOME=$PWD/home

    # webp images can't be included directly, need to convert to PNG
    convert ${depot.tvix.website}/tvix-logo.webp tvix-logo.png

    # As usual, TeX needs to be run twice ...
    ${tex}/bin/xelatex presentation.tex
    ${tex}/bin/xelatex presentation.tex
  '';

  installPhase = ''
    mkdir -p $out
    cp presentation.pdf $out/
    cp $src/presentation.pdfpc $out/
  '';
}