users/grfn/system/home/modules/obs.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68

{ config, lib, pkgs, ... }:

with pkgs;

let
  libuiohook = stdenv.mkDerivation rec {
    pname = "libuiohook";
    version = "1.1";
    src = fetchFromGitHub {
      owner = "kwhat";
      repo = "libuiohook";
      rev = version;
      sha256 = "1isfxn3cfrdqq22d3mlz2lzm4asf9gprs7ww2xy9c3j3srk9kd7r";
    };

    preConfigure = ''
      ./bootstrap.sh
    '';

    nativeBuildInputs = [ pkg-config ];
    buildInputs = [
      libtool
      autoconf
      automake
      xlibsWrapper
      xorg.libXtst
      xorg.libXinerama
      xorg.libxkbfile
      libxkbcommon
    ];
  };

  obs-input-overlay = stdenv.mkDerivation rec {
    pname = "obs-input-overlay";
    version = "4.8";
    src = fetchFromGitHub {
      owner = "univrsal";
      repo = "input-overlay";
      rev = "v${version}";
      sha256 = "1dklg0dx9ijwyhgwcaqz859rbpaivmqxqvh9w3h4byrh5pnkz8bf";
      fetchSubmodules = true;
    };

    nativeBuildInputs = [ cmake ];
    buildInputs = [ obs-studio libuiohook ];

    postPatch = ''
      sed -i CMakeLists.txt \
        -e '2iinclude(${obs-studio.src}/cmake/Modules/ObsHelpers.cmake)' \
        -e '2ifind_package(LibObs REQUIRED)'
    '';

    cmakeFlags = [
      "-Wno-dev"
    ];
  };
in
{
  home.packages = [
    obs-studio
    obs-input-overlay
  ];

  xdg.configFile."obs-studio/plugins/input-overlay/bin/64bit/input-overlay.so".source =
    "${obs-input-overlay}/lib/obs-plugins/input-overlay.so";
  xdg.configFile."obs-studio/plugins/input-overlay/data".source =
    "${obs-input-overlay}/share/obs/obs-plugins/input-overlay";
}