users/glittershark/system/system/modules/reusable/battery.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32

{ config, lib, pkgs, ... }:
with lib;
{
  options = {
    laptop.onLowBattery = {
      enable = mkEnableOption "Perform action on low battery";

      thresholdPercentage = mkOption {
        description = "Threshold battery percentage on which to perform the action";
        default = 5;
        type = types.int;
      };

      action = mkOption {
        description = "Action to perform on low battery";
        default = "hibernate";
        type = types.enum [ "hibernate" "suspend" "suspend-then-hibernate" ];
      };
    };
  };

  config =
    let cfg = config.laptop.onLowBattery;
    in mkIf cfg.enable {
    services.udev.extraRules = concatStrings [
      ''SUBSYSTEM=="power_supply", ''
      ''ATTR{status}=="Discharging", ''
      ''ATTR{capacity}=="[0-${toString cfg.thresholdPercentage}]", ''
      ''RUN+="/${pkgs.systemd}/bin/systemctl ${cfg.action}"''
    ];
  };
}