tvix/store/protos/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

{ depot, pkgs, ... }:
let
  protos = depot.nix.sparseTree {
    name = "store-protos";
    root = depot.path.origSrc;
    paths = [
      # We need to include castore.proto (only), as it's referred.
      ../../castore/protos/castore.proto
      ./pathinfo.proto
      ./rpc_pathinfo.proto
      ../../../buf.yaml
      ../../../buf.gen.yaml
    ];
  };
in
depot.nix.readTree.drvTargets {
  inherit protos;

  # Lints and ensures formatting of the proto files.
  check = pkgs.stdenv.mkDerivation {
    name = "proto-check";
    src = protos;

    nativeBuildInputs = [
      pkgs.buf
    ];

    buildPhase = ''
      export HOME=$TMPDIR
      buf lint
      buf format -d --exit-code
      touch $out
    '';
  };

  # Produces the golang bindings.
  go-bindings = pkgs.stdenv.mkDerivation {
    name = "go-bindings";
    src = protos;

    nativeBuildInputs = [
      pkgs.buf
      pkgs.protoc-gen-go
      pkgs.protoc-gen-go-grpc
    ];

    buildPhase = ''
      export HOME=$TMPDIR
      buf generate

      mkdir -p $out
      cp tvix/store/protos/*.pb.go $out/
    '';
  };
}