blob: 54bd0d80eafe36e99a094247638f807483d3c5fb (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
|
# This file builds an Emacs pre-configured with the packages I need
# and my personal Emacs configuration.
{ pkgs, ... }:
with pkgs;
with third_party.emacsPackagesNg;
with third_party.emacs;
let
localPackages = pkgs.tools.emacs-pkgs;
emacsWithPackages = (third_party.emacsPackagesNgGen third_party.emacs26).emacsWithPackages;
identity = x: x;
tazjinsEmacs = pkgfun: (emacsWithPackages(epkgs: pkgfun(
# Actual ELPA packages (the enlightened!)
(with epkgs.elpaPackages; [
ace-window
avy
pinentry
rainbow-mode
undo-tree
]) ++
# MELPA packages:
(with epkgs.melpaPackages; [
browse-kill-ring
cargo
clojure-mode
counsel
counsel-notmuch
dash-functional
direnv
dockerfile-mode
elixir-mode
elm-mode
erlang
exwm
go-mode
gruber-darker-theme
haskell-mode
ht
hydra
idle-highlight-mode
intero
ivy
ivy-pass
ivy-prescient
jq-mode
kotlin-mode
lsp-mode
magit
markdown-toc
multi-term
multiple-cursors
nginx-mode
nix-mode
notmuch # this comes from pkgs.third_party
paredit
password-store
pg
prescient
racket-mode
rainbow-delimiters
refine
restclient
request
sly
string-edit
swiper
telephone-line
terraform-mode
toml-mode
transient
use-package
uuidgen
vterm
web-mode
websocket
which-key
xelb
yaml-mode
]) ++
# Custom packages
[ carp-mode localPackages.dottime localPackages.term-switcher ]
)));
in lib.fix(self: l: f: third_party.writeShellScriptBin "tazjins-emacs" ''
exec ${tazjinsEmacs f}/bin/emacs \
--debug-init \
--no-site-file \
--no-site-lisp \
--no-init-file \
--directory ${./config} ${if l != null then "--directory ${l}" else ""} \
--eval "(require 'init)" $@
'' // {
# Call overrideEmacs with a function (pkgs -> pkgs) to modify the
# packages that should be included in this Emacs distribution.
overrideEmacs = f': self l f';
# Call withLocalConfig with the path to a *folder* containing a
# `local.el` which provides local system configuration.
withLocalConfig = confDir: self confDir f;
# Build a derivation that uses the specified local Emacs (i.e.
# built outside of Nix) instead
withLocalEmacs = emacsBin: third_party.writeShellScriptBin "tazjins-emacs" ''
exec ${emacsBin} \
--debug-init \
--no-site-file \
--no-init-file \
--directory ${(tazjinsEmacs f).deps}/share/emacs/site-lisp \
--directory ${./config} ${if l != null then "--directory ${l}" else ""} \
--eval "(require 'init)" $@
'';
}) null identity
|
