emacs.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150

# Derivation for Emacs configured with the packages that I need:
{ pkgs }:

let emacsWithPackages = with pkgs; (emacsPackagesNgGen emacs).emacsWithPackages;
sly = with pkgs; emacsPackagesNg.melpaBuild {
  pname   = "sly";
  version = "20180221.1414";

  src = fetchFromGitHub {
    owner  = "joaotavora";
    repo   = "sly";
    rev    = "486bfbe95612bcdc0960c490207970a188e0fbb9";
    sha256 = "0ib4q4k3h3qn88pymyjjmlmnpizdn1mfg5gpk5a715nqsgxlg09l";
  };

  recipeFile = fetchurl {
    url    = "https://raw.githubusercontent.com/melpa/melpa/23b9e64887a290fca7c7ab2718f627f8d728575f/recipes/sly";
    sha256 = "1pmyqjk8fdlzwvrlx8h6fq0savksfny78fhmr8r7b07pi20y6n9l";
    name   = "sly";
  };
};

# Building sly-company requires quite some dancing because
# company-mode is required at build time.
trivialBuildWithCompany = with pkgs; callPackage <nixos/pkgs/build-support/emacs/trivial.nix> {
  emacs = with pkgs; emacsWithPackages(epkgs: [ epkgs.elpaPackages.company ]);
};

sly-company = with pkgs; trivialBuildWithCompany {
  pname   = "sly-company";
  version = "master";

  src = fetchFromGitHub {
    owner  = "joaotavora";
    repo   = "sly-company";
    rev    = "dfe18218e4b2ee9874394b50f82f5172f41c462c";
    sha256 = "1bj8w2wfq944cnhsk5xx41mfrjv89scrg4w98kqgda5drkpdf8a7";
  };
};

# The nix-mode in the official repositories is old and annoying to
# work with, pin it to something newer instead:
nix-mode = with pkgs; emacsPackagesNg.melpaBuild {
  pname   = "nix-mode";
  version = "20180306";

  src = fetchFromGitHub {
    owner  = "NixOS";
    repo   = "nix-mode";
    rev    = "0ac0271f6c8acdbfddfdbb1211a1972ae562ec17";
    sha256 = "157vy4xkvaqd76km47sh41wykbjmfrzvg40jxgppnalq9pjxfinp";
  };

  recipeFile = writeText "nix-mode-recipe" ''
    (nix-mode :repo "NixOS/nix-mode" :fetcher github
              :files (:defaults (:exclude "nix-mode-mmm.el")))
  '';
};

# The default Rust language server mode is not really usable, install
# `eglot` instead and hope for the best.
eglot = with pkgs; emacsPackagesNg.melpaBuild rec {
  pname = "eglot";
  version = "0.8";

  src = fetchFromGitHub {
    owner  = "joaotavora";
    repo   = "eglot";
    rev    = version;
    sha256 = "1avsry84sp3s2vr2iz9dphm579xgw8pqlwffl75gn5akykgazwdx";
  };
};

# prescient & prescient-ivy provide better filtering in ivy/counsel
prescient = with pkgs; emacsPackagesNg.melpaBuild {
  pname = "prescient";
  version = "20180611";

  src = fetchFromGitHub {
    owner  = "raxod502";
    repo   = "prescient.el";
    rev    = "19a2c6b392ca6130dbbcf70cba57ee34d64fe50c";
    sha256 = "136q785lyhpgyaiysyq4pw11l83sa9h3q57v6papx813gf7rb7v7";
  };

  recipeFile = writeText "prescient-recipe" ''
    (prescient :files ("prescient.el" "ivy-prescient.el"))
  '';
};

in emacsWithPackages(epkgs:
  # Pinned packages (from unstable):
  (with pkgs; with lib; attrValues pinnedEmacs) ++

  # Actual ELPA packages (the enlightened!)
  (with epkgs.elpaPackages; [
    ace-window
    adjust-parens
    avy
    company
    pinentry
    rainbow-mode
    undo-tree
    which-key
  ]) ++

  # MELPA packages:
  (with epkgs.melpaPackages; [
    browse-kill-ring
    cargo
    dash
    dash-functional
    dockerfile-mode
    edit-server
    elm-mode
    erlang
    flx
    go-mode
    gruber-darker-theme
    haskell-mode
    ht
    idle-highlight-mode
    jq-mode
    kotlin-mode
    magit
    multi-term
    multiple-cursors
    nginx-mode
    paredit
    password-store
    pg
    racket-mode
    rainbow-delimiters
    restclient
    rust-mode
    s
    smartparens
    string-edit
    terraform-mode
    telephone-line
    toml-mode
    uuidgen
    web-mode
    websocket
    yaml-mode
  ]) ++

  # Custom packaged Emacs packages:
  [ sly sly-company nix-mode eglot prescient pkgs.notmuch ]
)