feat(tazjin/homepage): Add Atom feed for blog posts r/1636

Change-Id: I9049e2cc3f5a2c491ccfad5595d60c01ad926e6d
Reviewed-on: https://cl.tvl.fyi/c/depot/+/1712
Tested-by: BuildkiteCI
Reviewed-by: tazjin <mail@tazj.in>

1 files changed, 40 insertions, 0 deletions

diff --git a/users/tazjin/homepage/feed.nix b/users/tazjin/homepage/feed.nix
new file mode 100644
index 000000000000..1f9d7c91fbce
--- /dev/null
+++ b/users/tazjin/homepage/feed.nix
@@ -0,0 +1,40 @@
+# Creates the Atom feed for my homepage.
+{ depot, lib, pkgs, ... }:
+
+with depot.nix.yants;
+
+let
+  inherit (builtins) map readFile;
+  inherit (lib) singleton;
+  inherit (pkgs) writeText;
+  inherit (depot.users.tazjin) atom-feed blog renderMarkdown;
+
+  postToEntry = defun [ blog.post atom-feed.entry ] (post: rec {
+    id = "https://tazj.in/blog/${post.key}";
+    title = post.title;
+    content = readFile (renderMarkdown post.content);
+    published = post.date;
+    updated = post.date; # TODO(tazjin): this should be distinct from published
+
+    links = singleton {
+      rel = "alternate";
+      href = id;
+    };
+  });
+
+  feed = {
+    id = "https://tazj.in/";
+    title = "tazjin's interblag";
+    # TODO(tazjin): Take the most recently updated entry time instead.
+    updated = builtins.currentTime;
+    rights = "© 2020 tazjin";
+    authors = [ "tazjin" ];
+
+    links = singleton {
+      rel = "self";
+      href = "https://tazjin/feed.atom";
+    };
+
+    entries = map postToEntry blog.posts;
+  };
+in writeText "feed.atom" (atom-feed.renderFeed feed)