* Move the implementation of the ‘derivation’ primop into a separate

  file.

1 files changed, 31 insertions, 0 deletions

diff --git a/corepkgs/derivation.nix b/corepkgs/derivation.nix
new file mode 100644
index 000000000000..0e16ad6fa300
--- /dev/null
+++ b/corepkgs/derivation.nix
@@ -0,0 +1,31 @@
+attrs:
+
+let
+
+  strict = derivationStrict attrs;
+  
+  attrValues = attrs:
+    map (name: builtins.getAttr name attrs) (builtins.attrNames attrs);
+    
+  outputToAttrListElement = output:
+    { name = output;
+      value = attrs // {
+        outPath = builtins.getAttr (output + "Path") strict;
+        drvPath = strict.drvPath;
+        type = "derivation";
+        currentOutput = output;
+      } // outputsAttrs // { all = allList; };
+    };
+    
+  outputsList =
+    if attrs ? outputs
+    then map outputToAttrListElement attrs.outputs
+    else [ (outputToAttrListElement "out") ];
+    
+  outputsAttrs = builtins.listToAttrs outputsList;
+  
+  allList = attrValues outputsAttrs;
+  
+  head = if attrs ? outputs then builtins.head attrs.outputs else "out";
+  
+in builtins.getAttr head outputsAttrs