Fix buffer switch problems

* Prevent switching to floating windows or windows on other workspaces
* Provide a workaround for `ido-mode` (can be enabled with
  `(exwm-enable-ido-workaround)`)

2 files changed, 31 insertions, 1 deletions

diff --git a/exwm-layout.el b/exwm-layout.el
index 5d056afeb505..f2d4eb0cbeb9 100644
--- a/exwm-layout.el
+++ b/exwm-layout.el
@@ -198,7 +198,13 @@
                 (exwm-layout--hide exwm--id)
               (exwm-layout--show exwm--id (car windows))
               (dolist (i (cdr windows))
-                (set-window-buffer i placeholder)))))))))
+                (set-window-buffer i placeholder))))))
+      ;; Make sure windows floating / on other workspaces are excluded
+      (dolist (window (window-list frame 0))
+        (with-current-buffer (window-buffer window)
+          (when (and (eq major-mode 'exwm-mode)
+                     (or exwm--floating-frame (not (eq frame exwm--frame))))
+            (set-window-buffer window placeholder)))))))
 
 (defun exwm-layout--on-minibuffer-setup ()
   "Refresh layout when minibuffer grows."
diff --git a/exwm.el b/exwm.el
index 95b674243cee..7e909cdef681 100644
--- a/exwm.el
+++ b/exwm.el
@@ -707,6 +707,30 @@
     (add-hook 'window-setup-hook 'exwm-init t)            ;for Emacs
     (add-hook 'after-make-frame-functions 'exwm-init t))) ;for Emacs Client
 
+(defun exwm--ido-buffer-window-other-frame (orig-fun buffer)
+  "Wrapper for `ido-buffer-window-other-frame' to exclude invisible windows."
+  (let* ((window (funcall orig-fun buffer))
+         (frame (window-frame window)))
+    ;; Exclude windows on other workspaces
+    (unless (and (memq frame exwm-workspace--list)
+                 (not (eq frame exwm-workspace--current)))
+      window)))
+
+(defun exwm--fix-ido-buffer-window-other-frame ()
+  "Fix `ido-buffer-window-other-frame'."
+  (advice-add 'ido-buffer-window-other-frame :around
+              'exwm--ido-buffer-window-other-frame))
+
+(defun exwm-enable-ido-workaround ()
+  "Enable workarounds for `ido-mode'."
+  (add-hook 'exwm-init-hook 'exwm--fix-ido-buffer-window-other-frame))
+
+(defun exwm-disable-ido-workaround ()
+  "Disable workarounds for `ido-mode'."
+  (remove-hook 'exwm-init-hook 'exwm--fix-ido-buffer-window-other-frame)
+  (advice-remove 'ido-buffer-window-other-frame
+                 'exwm--ido-buffer-window-other-frame))
+
 
 
 (provide 'exwm)