about summary refs log blame commit diff
path: root/third_party/nixpkgs/default.nix
blob: fa42b5bb7b6dba1207ed2b8a49cb28b33e418203 (plain) (tree)
1
2
3
4
5
6
7
8
9







                                                                      
                             





                                                                      
                                             
                    

                                                                    

    
                                          
                  

                                                                    

    





                                                                    

                                                                                     

     











                                                                                   
                                          







                                      
                                    

    
# This file imports the pinned nixpkgs sets and applies relevant
# modifications, such as our overlays.
#
# Note that the attribute exposed by this (third_party.nixpkgs) is
# "special" in that the fixpoint used as readTree's config parameter
# in //default.nix passes this attribute as the `pkgs` argument to all
# readTree derivations.

{ depot, externalArgs, ... }:

let
  # This provides the sources of nixpkgs. We track both
  # nixos-unstable, and the current stable channel of the latest NixOS
  # release.

  # Tracking nixos-unstable as of 2021-08-11.
  unstableHashes = {
    commit = "fe01052444c1d66ed6ef76df2af798c9769e9e79";
    sha256 = "0z99hwxgrvlf0psicwd97kdqqcc3qngfzmcz7k68q6q868y8582y";
  };

  # Tracking nixos-21.05 as of 2021-08-11.
  stableHashes = {
    commit = "2d6ab6c6b92f7aaf8bc53baba9754b9bfdce56f2";
    sha256 = "1aafqly1mcqxh0r15mrlsrs4znldhm7cizsmfp3d25lqssay6gjd";
  };

  # import the nixos-unstable package set, or optionally use the
  # source (e.g. a path) specified by the `nixpkgsBisectPath`
  # argument. This is intended for use-cases where the depot is
  # bisected against nixpkgs to find the root cause of an issue in a
  # channel bump.
  nixpkgsSrc = externalArgs.nixpkgsBisectPath or (fetchTarball {
    url = "https://github.com/NixOS/nixpkgs/archive/${unstableHashes.commit}.tar.gz";
    sha256 = unstableHashes.sha256;
  });

  stableNixpkgsSrc = fetchTarball {
    url = "https://github.com/NixOS/nixpkgs/archive/${stableHashes.commit}.tar.gz";
    sha256 = stableHashes.sha256;
  };

  # Stable package set is imported, but not exposed, to overlay
  # required packages into the unstable set.
  stableNixpkgs = import stableNixpkgsSrc {};

  # Overlay for packages that should come from the stable channel
  # instead (e.g. because something is broken in unstable).
  stableOverlay = self: super: {
    # nothing picked from stable currently
  };
in import nixpkgsSrc {
  config.allowUnfree = true;
  config.allowBroken = true;
  overlays = [
    stableOverlay
    depot.third_party.overlays.tvl
    depot.third_party.overlays.haskell
    depot.third_party.overlays.emacs
  ];
}