about summary refs log tree commit diff
path: root/third_party/apereo-cas/overlay/build.gradle
blob: 2b04bbc5f0cce511f44a19f6d12fbaa0bcdafdbc (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
buildscript {
    repositories {
        if (rootProject.hasProperty("cacheLocation")) {
            mavenLocal()
            maven { url cacheLocation }
        } else {
            mavenLocal()
            gradlePluginPortal()
            mavenCentral()
            jcenter()
            maven {
                url "https://repo.spring.io/libs-milestone"
                mavenContent { releasesOnly() }
            }
            maven {
                url "https://repo.spring.io/libs-snapshot"
                mavenContent { snapshotsOnly() }
            }
            maven {
                url "https://plugins.gradle.org/m2/"
                mavenContent { releasesOnly() }
            }
        }
    }
    dependencies {
        classpath "de.undercouch:gradle-download-task:${project.gradleDownloadTaskVersion}"
        classpath "org.springframework.boot:spring-boot-gradle-plugin:${project.springBootVersion}"
        classpath "gradle.plugin.com.google.cloud.tools:jib-gradle-plugin:${project.jibVersion}"
        classpath "io.freefair.gradle:maven-plugin:${project.gradleMavenPluginVersion}"
        classpath "io.freefair.gradle:lombok-plugin:${project.gradleLombokPluginVersion}"
    }
}

repositories {
    if (rootProject.hasProperty("cacheLocation")) {
        mavenLocal()
        maven { url cacheLocation }
    } else {
        mavenLocal()
        mavenCentral()
        jcenter()
        maven {
            url "https://oss.sonatype.org/content/repositories/snapshots"
            mavenContent { snapshotsOnly() }
        }
        maven {
            mavenContent { releasesOnly() }
            url "https://build.shibboleth.net/nexus/content/repositories/releases/"
        }
        maven {
            mavenContent { releasesOnly() }
            url "https://repo.spring.io/milestone/"
        }
        maven {
            url "https://repo.spring.io/snapshot/"
            mavenContent { snapshotsOnly() }
        }
        maven {
            mavenContent { snapshotsOnly() }
            url "https://oss.jfrog.org/artifactory/oss-snapshot-local"
        }
    }
}

def casServerVersion = project.'cas.version'
def casWebApplicationBinaryName = "cas.war"

project.ext."casServerVersion" = casServerVersion
project.ext."casWebApplicationBinaryName" = casWebApplicationBinaryName

apply plugin: "io.freefair.war-overlay"
apply plugin: "io.freefair.lombok"
apply from: rootProject.file("gradle/tasks.gradle")

apply plugin: "war"
apply plugin: "eclipse"
apply plugin: "idea"

apply from: rootProject.file("gradle/springboot.gradle")
apply from: rootProject.file("gradle/dockerjib.gradle")

dependencies {
    // Other CAS dependencies/modules may be listed here...
    // implementation "org.apereo.cas:cas-server-support-json-service-registry:${casServerVersion}"
}

tasks.findByName("jibDockerBuild")
    .dependsOn(copyWebAppIntoJib, copyConfigIntoJib)
    .finalizedBy(deleteWebAppFromJib)

tasks.findByName("jib")
    .dependsOn(copyWebAppIntoJib, copyConfigIntoJib)
    .finalizedBy(deleteWebAppFromJib)

configurations.all {
    resolutionStrategy {
        cacheChangingModulesFor 0, "seconds"
        cacheDynamicVersionsFor 0, "seconds"

        preferProjectModules()

        def failIfConflict = project.hasProperty("failOnVersionConflict") && Boolean.valueOf(project.getProperty("failOnVersionConflict"))
        if (failIfConflict) {
            failOnVersionConflict()
        }
    }
}

eclipse {
    classpath {
       downloadSources = true
       downloadJavadoc = true
    }
}

idea {
    module {
        downloadJavadoc = true
        downloadSources = true
    }
}