about summary refs log tree commit diff
path: root/ci-builds.nix
blob: b36b29326679684e081752906ec997ec20d1c5d7 (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
# This file defines the derivations that should be built by CI.
#
# The "categories" (i.e. attributes) below exist because we run out of
# space on Sourcehut otherwise.
{ depot, lib, ... }:

let
  inherit (builtins) attrNames filter foldl' getAttr substring;

  # attach a nix expression to a drv so we can “build” it
  # TODO(Profpatsch): instead of failing evaluation if a test fails,
  # we can put the expression of the test failure into $out
  # and continue with the other CI derivations.
  drvify = name: exp: depot.nix.emptyDerivation {
    inherit name;
    owo = lib.generators.toPretty {} exp;
  };

in lib.fix (self: {
  __apprehendEvaluators = throw ''
    Do not evaluate this attribute set directly. It exists only to group builds
    for CI runs of different "project groups".

    To use the depot, always start from the top-level attribute tree instead.
  '';

  # Names of all evaluatable attributes in here. This list will be
  # used to trigger builds for each key.
  __evaluatable = filter (key: (substring 0 2 key) != "__") (attrNames self);

  # List of non-public targets, these are only used in local builds
  # and not in CI.
  __nonpublic = with depot; [
    users.tazjin.nixos.camdenSystem
    users.tazjin.nixos.frogSystem
  ];

  # Combined list of all the targets, used for building everything locally.
  __allTargets =
    (with depot.nix.yants; list drv)
      (foldl' (x: y: x ++ y) self.__nonpublic
        (map (k: getAttr k self) self.__evaluatable));

  fun = with depot.fun; [
    amsterdump
    gemma
    quinistry
    watchblob
    wcl
  ];

  gitAndFriends = with depot; [
    third_party.cgit
    third_party.git
    web.cgit-taz
  ];

  nix = [ depot.third_party.nix ];

  ops = with depot.ops; [
    depot.ops."posix_mq.rs"
    besadii
    journaldriver
    kontemplate
    mq_cli
  ];

  various = with depot; [
    depot.web.tvl
    lisp.dns
    nix.buildLisp.example
    nix.yants.tests
    tools.cheddar
    tools.nsfv-setup
    (drvify "getBins-tests" nix.getBins.tests)
  ];

  # Haskell packages we've patched locally
  haskellPackages = with depot.third_party.haskellPackages; [
    generic-arbitrary
    hgeometry
    hgeometry-combinatorial
    vinyl
    comonad-extras
  ];

  # User-specific build targets
  tazjin = with depot.users.tazjin; [
    blog.rendered
    emacs
    homepage
  ];
})