From 533e365c12b5097005626317171b789406c1780f Mon Sep 17 00:00:00 2001
From: Profpatsch <mail@profpatsch.de>
Date: Fri, 1 Jan 2021 18:55:33 +0100
Subject: feat(users/Profpatsch): add python3Lib writer

Smol writer to create a python lib directly from a nix string.
The resulting library can be consumed by the writePython3 writer.

Change-Id: Id3d793564d230b38a08f65140bda4287285e1a72
Reviewed-on: https://cl.tvl.fyi/c/depot/+/2310
Tested-by: BuildkiteCI
Reviewed-by: tazjin <mail@tazj.in>
---
 users/Profpatsch/writers/default.nix | 40 ++++++++++++++++++++++++++++++++++++
 users/Profpatsch/writers/tests.nix   | 22 ++++++++++++++++++++
 2 files changed, 62 insertions(+)
 create mode 100644 users/Profpatsch/writers/default.nix
 create mode 100644 users/Profpatsch/writers/tests.nix

(limited to 'users/Profpatsch/writers')

diff --git a/users/Profpatsch/writers/default.nix b/users/Profpatsch/writers/default.nix
new file mode 100644
index 000000000000..f775913d0026
--- /dev/null
+++ b/users/Profpatsch/writers/default.nix
@@ -0,0 +1,40 @@
+{ depot, pkgs, ... }:
+let
+  bins = depot.nix.getBins pkgs.coreutils ["printf" "mkdir" "cat"];
+
+  python3Lib = { name, libraries ? (_: []) }: moduleString:
+    let srcTree = depot.nix.runExecline.local name { stdin = moduleString; } [
+      "importas" "out" "out"
+      "if" [ bins.mkdir "-p" "\${out}/${name}" ]
+      "if" [
+        "redirfd" "-w" "1" "\${out}/setup.py"
+        bins.printf ''
+          from distutils.core import setup
+
+          setup(
+            name='%s',
+            packages=['%s']
+          )
+        '' name name
+      ]
+      "if" [
+        # redirect stdin to the init py
+        "redirfd" "-w" "1" "\${out}/${name}/__init__.py"
+        bins.cat
+      ]
+    ];
+    in pkgs.python3Packages.buildPythonPackage {
+      inherit name;
+      src = srcTree;
+      propagatedBuildInputs = libraries pkgs.python3Packages;
+      doCheck = false;
+    };
+
+  tests = import ./tests.nix { inherit depot pkgs python3Lib; };
+
+in {
+  inherit
+    python3Lib
+    tests
+    ;
+}
diff --git a/users/Profpatsch/writers/tests.nix b/users/Profpatsch/writers/tests.nix
new file mode 100644
index 000000000000..4cae230e0e6d
--- /dev/null
+++ b/users/Profpatsch/writers/tests.nix
@@ -0,0 +1,22 @@
+{ depot, pkgs, python3Lib }:
+
+let
+  testLib = python3Lib {
+    name = "test_lib";
+  } ''
+    def test():
+      return "test"
+  '';
+
+  pythonWithLib = pkgs.writers.writePython3 "python-with-lib" {
+    libraries = [ testLib ];
+  } ''
+    import test_lib
+
+    assert(test_lib.test() == "test")
+  '';
+
+in {
+  inherit
+    pythonWithLib;
+}
-- 
cgit 1.4.1